initial commit

[contactbook.git] / configure.ac

#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

AC_PREREQ(2.61)
AC_INIT(addressbook, 0.1, [mir@datanom.net])
AC_COPYRIGHT([Copyright (c) 2018 Michael Rasmussen.])
AC_CONFIG_MACRO_DIR([m4])
AC_CONFIG_AUX_DIR(auxdir)
AC_CANONICAL_SYSTEM

AC_CONFIG_SRCDIR([src/addressbook.c])
AM_INIT_AUTOMAKE([gnu no-dist-gzip dist-bzip2 1.10])
AC_CONFIG_HEADERS([config.h])
AM_MAINTAINER_MODE

CFLAGS="-g -Wall"

if test "x$USE_MAINTAINER_MODE" = "xyes"; then
    CFLAGS="${CFLAGS} -Werror -DDEBUG"
    AC_DEFINE_UNQUOTED(DEBUG, [1], [Enable debug mode.])
else
    CFLAGS="${CFLAGS} -O -O2"
fi

GLIB_REQUIRED=2.26.0
GOBJECT_REQUIRED=2.26.0
GTK_REQUIRED=2.18.0
SQLITE3_REQUIRED=3.5.0

AC_SUBST(GLIB_REQUIRED)
AC_SUBST(GOBJECT_REQUIRED)
AC_SUBST(GTK_REQUIRED)

# Checks for programs.
AC_PROG_CC
AC_PROG_CPP
AC_PROG_LIBTOOL
if test -n "$lt_prog_compiler_pic"; then
    CFLAGS="$CFLAGS $lt_prog_compiler_pic"
fi

PKG_PROG_PKG_CONFIG
AC_LIB_PREFIX

# Checks for libraries.
PKG_CHECK_MODULES([GLIB],
                  [glib-2.0 >= $GLIB_REQUIRED
                   gobject-2.0 >= $GOBJECT_REQUIRED
                   gmodule-2.0]
)
AC_SUBST(GLIB_CFLAGS)
AC_SUBST(GLIB_LIBS)

PKG_CHECK_MODULES([GTK], gtk+-2.0 >= $GTK_REQUIRED)
AC_SUBST(GTK_CFLAGS)
AC_SUBST(GTK_LIBS)

AC_ARG_ENABLE(sqlite,
        [AC_HELP_STRING([--enable-sqlite],[Build the included SQLite plugin [default=yes]])],
        [ac_enable_sqlite=$enableval],
        [ac_enable_sqlite=yes])

AC_MSG_CHECKING([whether to compile SQLite3 module])
if test x"$ac_enable_sqlite" = xyes; then
	AC_MSG_RESULT(yes)
    PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $SQLITE3_REQUIRED],
    				  [ac_enable_sqlite=yes],
    				  [ac_enable_sqlite=no])
    AC_SUBST(SQLITE3_LIBS)
    AC_SUBST(SQLITE3_CFLAGS)
    if test x"$ac_enable_sqlite" = "xno"; then
    	AC_MSG_RESULT([$SQLITE3_PKG_ERRORS])
    fi
fi
AM_CONDITIONAL(BUILD_SQLITE, test x"$ac_enable_sqlite" = "xyes")

AC_ARG_WITH([moduledir],
        [AC_HELP_STRING([--with-moduledir[[=DIR]]],[Build the included SQLite plugin [default=yes]])],
        [with_moduledir=$withval],
        [with_moduledir=check])

if test "x$with_moduledir" = "xcheck"; then
	if test "x$USE_MAINTAINER_MODE" = "xyes"; then
	    PLUGINDIR="${ac_pwd}/src/libaddressbook"
	    plugindir="${ac_pwd}/src/libaddressbook"
	else
	    if test "x$prefix" = "xNONE"; then
	        prefix=$ac_default_prefix
	    fi
	    PLUGINDIR="${prefix}/lib/addressbook/plugins"
	    plugindir="${prefix}/lib/addressbook/plugins"
	fi
else
    PLUGINDIR="$with_moduledir"
    plugindir="$with_moduledir"
fi
AC_SUBST(PLUGINDIR)
AC_DEFINE_UNQUOTED(PLUGINDIR, "$plugindir", [Define plugin dir.])

# Checks for header files.
AC_CHECK_HEADER([assert.h],
		AC_DEFINE([HAVE_ASSERT_H], [1], [Define to 1 if you have the <assert.h> header file.]))

# Checks for typedefs, structures, and compiler characteristics.

# Checks for library functions.

AC_CONFIG_FILES([
                 Makefile
                 src/Makefile
                 sqlite_plugin/Makefile
])

AC_OUTPUT
echo "
Configuration:

        Source code:            ${ac_pwd}
        Plugin dir:             ${plugindir}
        Compiler:               ${CC} $($CC -dumpversion)
        CFLAGS:                 ${CFLAGS}
"